Nachbarn festlegen

Hallo Ron,

hier ist erstmal ein Skript, das dir die Nachbarn notiert:

' View.PolygonNoteNeighbors

' Schreibt die ID (Zahl oder Name) aller Nachbarn
' eines jeden Polygons des ersten aktiven Polygon-
' themas im View in eine neue Tabelle:

' [Class] [Neighbor]
' PlgA PlgB
' PlgA PlgC
' PlgA PlgF
' PlgB PlgA
' PlgB PlgC
' ... ...

' In der Tabelle des Polygonthemas wird ein Feld benötigt, das
' die Polygone eindeutig identifiziert (RecNo, Name, o.ä.)

'--------------------------------------------------
' GET VIEW, THEME AND TABLE

theView = av.GetActiveDoc
if (theView.Is(View).Not) then return NIL end

theActThms = theView.GetActiveThemes
if (theActThms.Count = 0) then return NIL end

theThm = theActThms.Get(0)
if (theThm.Is(FTheme).Not) then return NIL end

theVTab = theThm.GetFTab
theCN = theVTab.GetShapeClass.GetClassName
if (theCN <> "Polygon") then return NIL end
nRecs = theVTab.GetNumRecords
'--------------------------------------------------
' GET THE IDENTIFIER FIELD, OBTAIN SOME INFO

theFlds = theVTab.GetFields
theIDFld = MsgBox.List(theFlds,"Feld auswaehlen, "+
"das die Polygone eindeutig identifieziert",
"Identifier:"++theThm.GetName)
if (theIDFld = NIL) then return NIL end
theIDName = theIDFld.GetName
theIDType = theIDFld.GetType
theIDWdth = theIDFld.GetWidth
theIDPrec = theIDFld.GetPrecision

'--------------------------------------------------
' GET SHAPE FIELD

theShpFld = theVTab.FindField("Shape")
if (theShpFld = NIL) then return NIL end
'--------------------------------------------------
' CREATE OUTPUT VTAB WITH FIELDS

theCWD = FileName.getCWD

if (File.isWritable(theCWD).not) then
av.GetProject.GetWorkDIR.setCWD
theCWD = FileName.getCWD
end

theDefNm = theCWD.MakeTMP("Nachb","dbf")

theOutFN = FileDialog.Put(theDefNm,"*.dbf","Output table")
if (theOutFN = nil) then return NIL end

theClassFld = Field.Make(theIDName,theIDType,theIDWdth,theIDPrec)
theParaFld = Field.Make(theIDName.Left(7)+"_NB",theIDType,theIDWdth,theIDPrec)

theNuVTab = VTab.MakeNew(theOutFN,dBase)
theNuVTab.AddFields({theClassFld,theParaFld})

'--------------------------------------------------
' FIND NEIGHBORS

i = 0
for each rec in theVTab
progress = (i/nRecs) * 100
av.ShowMsg("Besuche Nachbarn...")
goesAhead = av.setStatus(progress)
if (not goesAhead) then break end
av.ShowStopButton

theID = theVTab.ReturnValue(theIDFld,rec)
theShp = theVTab.ReturnValue(theShpFld,rec)

theThm.SelectByShapes({theShp},#VTAB_SELTYPE_NEW)

for each theSel in theVTab.GetSelection
theID2 = theVTab.ReturnValue(theIDFld,theSel)
if (theID = theID2) then continue end
theNuRec = theNuVTab.AddRecord
theNuVTab.SetValue(theClassFld,theNuRec,theID)
theNuVTab.SetValue(theParaFld,theNuRec,theID2)
end
i = i + 1
end
'--------------------------------------------------
' TIDY UP AND CREATE TABLE FROM VTAB

av.ClearStatus
av.ShowMsg("Fertig...")

theVTab.GetSelection.ClearAll
theNuVTab.SetEditable(FALSE)
theNuTab = Table.Make(theNuVTab)
theNuTab.SetName(theNuVTab.GetName)
theNuTab.GetWin.Open
'--------------------------------------------------

'THE END

Nun hast du eine Tabelle im Format

[CL], [NB]
PlgA, PlgB
PlgA, PlgC
PlgA, PlgF
PlgB, PlgA
PlgB, PlgC
...

Auf diese Tabelle kannst du jetzt die Memo-Tools Funktion "Feld in Datensatz schreiben" anwenden, wobei du [CL] als Klassenfeld und [NB] als Parameterfeld definierst.

Das ergibt eine weitere Tabelle im Format

[CL], [NB1], [NB2], [NB3],
PlgA, PlgB, PlgC, PlgF
PlgB, PlgA, PlgC
...

d.h. eine Tabelle, in der jede Polygon-ID eindeutig mit seinen Nachbarn in Feldern aufgeführt ist. Diese Tabelle kannst du nun über das [CL] bzw. ID-Feld mittels 'Tabelle | Verbinden' an das Polygonshape hängen.
Fertig...

Gruß von Maxilla

Ach ja, die Inseln: Alle Polygone, die eine Küste haben (also das Meer selber als Nachbarpolygon) sind automatisch "Wassernachbarn"... Aber ich wohne in Hannover, und denke, Hannover ist weit genug von der Küste entfernt, um das für einen Scherz zu halten ;o)

Hi Ron,

na jut, also kein Scherz mit Inseln... Dann frag ich mich aber, wer z.B. die Nachbarn von Amrum sind? Nur Föhr (als nearest neighbour)? Oder auch Sylt? Was ist mit Dagebüll? Oder Brunsbüttel? Und nach Fehmarn kommt man auch, ohne eine andere Gemeinde zu durchqueren...

Ich meine: Bedarfs da nicht einer (Neu-)Definition von "Nachbarschaft" - oder gibt's die schon?

Gruß von gannnz kurz oberhalb des Weißwurstäquators
M.

NochNSherlock ;o)

Hallo Ron,

ich meinte, es käme darauf an, zu schauen welche Nachbarn deine Meerespolygone selber haben:

Angenommen du hast ein Meerespolygon mit einem dir zur Nachbarschaftsbestimmung angemessen erscheinenden (?) Radius erstellt, das z.B. alle Nachbarn Amrums definieren soll und dieses in dein Gemeindeshape eingebaut. Die Nachbarschaftsanalyse ergibt nun für dieses Wasserpolygon die Nachbarn Föhr, Sylt und Amrum. So hat also Amrum die "Wassernachbarn" Föhr und Sylt, Föhr hat wiederum die Nachbarn Sylt und Amrum uswusf - d.h. alle Nachbarpolygone, die für das zugehörige Wasserpolygon notiert wurden sind automatisch "Wassernachbarn" (if you know what I mean :)

Maxilla

Hallo Ron, Hallo Maxilla,

ich bin eher durch Zufall auf diesen Thread gestossen. Er schien mir sehr hilfreich da gelegentlich benachbarte Flurstücke gesucht werden müssen.

Die Suche nach den Nachbarn verlief sehr schnell aber die Funktion "Feld in Datensatz schreiben" läuft jetzt schon fast einen Tag. Bisher wurden aber erst 10% der Tabelleneinträge gefüllt. Läuft das bei euch auch sol langsam? Kann man das Verfahren beschleuningen? Ich kann doch meinen Rechner nicht 2 Wochen durchlaufen lassen (Prozessorlast: 100%)

Gruß
GisMoe

Also die Ergebnistabelle des Skriptes hat ca. 500.000 Einträge. Das würde die etwas längere Laufzeit begründen ;-)))

Gibt es nach erfolgreichem Durchlauf die Möglichkeit das man sich per einfachem Klick alle Nachbarn anzeigen/markieren lassen kann?

Ich habe es mit verbundenen Tabellen versucht. Aber die Richtung die benötige liefert mir eine 1:n - Verbindung!

Gruß GisMoe

Dafür gibt's den Eintrag 'Tabelle | Verknüpfen'